Revit Ribbon API & VB.NET: PushButton and Separator

The Ribbon PushButton is a reaction item that will trigger a command when clicked and the Ribbon Separator is a vertical thin line for display purpose only that can visually separate two ribbon items or groups left and right.

We demonstrated how to create PushButton and Separator items of Revit Ribbon API before in C#. In this article, let us see how to do so in VB.NET.

It is always good to start with some succinct, cool, and still relatively complete code:

    ' Create two Ribbon Panels to host the same items and add one Panel to the 'AddIn' Ribbon Tab
    ' and the other to the custom 'RevitAddinWizard' Ribbon Tab if applicable in Revit 2012.
    Function CreateRibbonPanel() As RibbonPanel
        Dim prefix As String = "ABC"    'VendorId for example
        Dim tabName1 As String = "AddIn"
        Dim tabName2 As String = "RevitAddinWizard"
        Dim panelTile As String = "Revit2012VBAddin"
        Dim panelNameFormat As String = "{0}_{1}_{2}_{3}"

        ' This addes the new Ribbon Panel to the default native 'AddIn' Ribbon Tab in both Revit 2011 and 2012.
        Dim panel As RibbonPanel = _cachedUiCtrApp.CreateRibbonPanel(Guid.NewGuid().ToString())
        panel.Name = String.Format(panelNameFormat, prefix, tabName1, panelTile, 1) ' Unique and still possible to parse!
        panel.Title = panelTile
        AddRibbonItemsToRibbonPanel(panel)

        ' This addes the new Ribbon Panel to the custom 'RevitAddinWizard' Ribbon Tab in Revit 2012 only.
        Try ' To avoid exceptions in case the same code is tried in Revit 2011
            _cachedUiCtrApp.CreateRibbonTab(tabName2)
            Dim panel1 As RibbonPanel = _cachedUiCtrApp.CreateRibbonPanel(tabName2, Guid.NewGuid().ToString())
            panel1.Name = String.Format(panelNameFormat, prefix, tabName2, panelTile, 1) ' Unique and still possible to parse!
            panel1.Title = panelTile
            AddRibbonItemsToRibbonPanel(panel1)
        Catch
        End Try

        Return panel
    End Function

    ' Create PushButton and Separator Ribbon items
    Public Sub AddRibbonItemsToRibbonPanel(ByVal panel As RibbonPanel)
        Dim assemFullName As String = Assembly.GetExecutingAssembly().Location
        Dim assemPath As String = Path.GetDirectoryName(assemFullName)

        Dim cnt1Panel_grp0_item1Data As New PushButtonData("cnt1Panel_grp0_item1", "PushButton1", assemFullName, "Revit2012VBAddin.ExtCmd")
        Dim cnt1Panel_grp0_item1 As PushButton = TryCast(panel.AddItem(cnt1Panel_grp0_item1Data), PushButton)
        cnt1Panel_grp0_item1.ToolTip = "A PushButton with the default image."
        cnt1Panel_grp0_item1.LargeImage = BmpImageSource("Revit2012VBAddin.ExtCmd.bmp")

        panel.AddSeparator()

        Dim cnt1Panel_grp0_item3Data As New PushButtonData("cnt1Panel_grp0_item3", "PushButton2", assemFullName, "Revit2012VBAddin.ExtCmd1")
        Dim cnt1Panel_grp0_item3 As PushButton = TryCast(panel.AddItem(cnt1Panel_grp0_item3Data), PushButton)
        cnt1Panel_grp0_item3.ToolTip = "A PushButton with a new image."
        cnt1Panel_grp0_item3.LargeImage = BmpImageSource("Revit2012VBAddin.BigA.bmp")
    End Sub

    ' Retrieve a Bitmap image resource
    Public Shared Function BmpImageSource(ByVal embeddedPath As String) As System.Windows.Media.ImageSource
        Dim stream As Stream = Assembly.GetExecutingAssembly().GetManifestResourceStream(embeddedPath)
        Dim decoder = New System.Windows.Media.Imaging.BmpBitmapDecoder(stream, BitmapCreateOptions.PreservePixelFormat, BitmapCacheOption.Default)
        Return decoder.Frames(0)
    End Function

The PushButton creation is not hard to follow, creating a PushButtonData object first, assigning its constructor’s arguments such as item name, display name, assembly location and the command to associate with, creating a PushButton through calling the AddItem method of the RibbonPanel and passing the created PushButtonData object to it, and finally setting other properties such as ToolTip and  LargeImage if necessary.

Creating a separator is nothing more than straightforward, calling the AddSeparator() method of the Ribbon Panel when timing is good. No arguments and no return value!

The BmpImageSource() is a helper method  that can be used by a Ribbon item to retrieve a specific bitmap image for its Image or LargeImage property if any from the Embedded Resources. It may be worth of mentioning the resource name here with a few words. In VB.NET, it is generally the project Default Namespace plus the image file name regardless whether the file is put into a project folder or not. However, in C#, things are different. We have to add the folder name if any in between.  

The CreateRibbonPanel() is another helper method that will create Ribbon Panels and add them to the default native ‘AddIn’ (API name, the UI name is ‘Add-Ins’) Ribbon Tab and to our custom ‘RevitAddinWizard’ Ribbon Tab (the API name and the UI name are the same) respectively. It applies some good naming conventions and follows some good coding practices such as always feeding a GUID to the panel constructor and then setting its Name as easy to remember/parse and still unique and its Title as good for display which can be duplicate.

The AddIn (API name) or Add-Ins (UI name) Ribbon Tab may look like the following:
 
The RevitAddinWizard (both API and UI name) Ribbon Tab may look like this:

As can be seen, except for in different Ribbon Tabs, the Ribbon Panel and its two PushButton items and one Separator look exactly the same.

The RevitAddinWizard is going to provide the VB.NET version of the Ribbon Creator soon.